|X Close
X Remove Iris:WebKitNetworkProcess2-debug
X Remove Iris:WebKitWebProcess1-debug
X Remove Iris:WebKitWebProcess3-debug
|
SetEval Iris$copyicons 1
IfThere Choices:icons Then SetEval Iris$copyicons 0
If <Iris$copyicons>=1 Then copy Iris:gtk <Choices$Write>.gtk ~CF~NR~V
Unset Iris$copyicons
|
|RMensure Reporter 2.65 Error Iris requires Reporter 2.65 or later - you appear to have an older version on your computer
|
RMEnsure AcornURI 0.12 Filer_Run System:Modules.Network.URI
|
RMEnsure ARMEABISupport 1.04 IfThere System:Modules.ARMEABISupport Then RMLoad System:Modules.ARMEABISupport
RMEnsure ARMEABISupport 1.04 IfThere Iris:ARMEABISupport Then RMLoad Iris:ARMEABISupport
RMEnsure ARMEABISupport 1.04 Error Iris requires ARMEABISupport (v1.04 or better).
|
RMEnsure CryptRandom 0.13 IfThere System:Modules.CryptRand Then RMLoad System:Modules.CryptRand
RMEnsure CryptRandom 0.13 IfThere Iris:CryptRand Then RMLoad Iris:CryptRand
RMEnsure CryptRandom 0.13 Error Iris requires the CryptRandom module
|
RMEnsure SharedUnixLibrary 1.16 IfThere System:Modules.SharedULib Then RMLoad System:Modules.SharedULib
RMEnsure SharedUnixLibrary 1.16 IfThere Iris:SharedULib Then RMLoad Iris:SharedULib
RMEnsure SharedUnixLibrary 1.16 Error Iris requires version 1.16 of the SharedULib module
|
| Check OS 5.28 because a modern RISC OS is a good thing
RMEnsure UtilityModule 5.27 /Iris:OS528
|
| Alignment Exceptions need to be turned off for Thumb2 JIT, so make sure that they are
/Iris:AlignExOff
|
Set UnixEnv$iris$sfix ""
|
If "<CaCertificates$Dir>"="" Then Run Iris:!CaCertificates
Run Iris:!UnixFC
Run Iris:!UnixFont
Run Iris:SharedLibs.!SharedLibs
|
Set File$Type_FAF HTML
Set File$Type_F91 URI
Set File$Type_F81 JSScript
Set File$Type_695 GIF
Set File$Type_C85 JPEG
Set File$Type_B60 PNG

| URI handler support

Set Alias$Open_URI_http   <Iris$Dir>.!Run2
Set Alias$Open_URI_https  <Iris$Dir>.!Run2
Set Alias$Open_URI_ftp    <Iris$Dir>.!Run2
Set Alias$Open_URI_gopher <Iris$Dir>.!Run2
Set Alias$Open_URI_file   <Iris$Dir>.!Run2

| Support the ANT URL protocol

SetMacro Alias$URLOpen_HTTP   Run <Iris$Dir>.!Run --url %%*0
SetMacro Alias$URLOpen_HTTPS  Run <Iris$Dir>.!Run --url %%*0
SetMacro Alias$URLOpen_Gopher Run <Iris$Dir>.!Run --url %%*0
SetMacro Alias$URLOpen_File   Run <Iris$Dir>.!Run --url %%*0
SetMacro Alias$URLOpen_FTP    Run <Iris$Dir>.!Run --url %%*0

Set Alias$@RunType_FAF <Iris$Dir>.!Run --html %%*0
Set Alias$@RunType_F91 <Iris$Dir>.!Run --uri %%*0
Set Alias$@RunType_F81 <Iris$Dir>.!Run --jss %%*0
Set Alias$@RunType_B28 <Iris$Dir>.!Run --url %%*0
|


WimpSlot -min 5000k -max 5000k
|
|set SOM$WritableText 1
Run <Iris$Dir>.!RunImage %*0 1>null:$ 2>&1